Global.asa
우리의 웹사이트를 들어오는 모든 방문자가 반드시 제일 처음 통과하는 관문으로, 방문자가 우리의 사이트의 어떤 페이지로 접근
한다해도 무조건 이 Global.asa 를 통과한 후 그 페이지로 자동으로 보내주게 된다. Global.asa 에는 4개의 주요 이벤트를 감지하는
책임이 있다.
그 4개의 이벤트는 Application_OnStart 와 Application_OnEnd 그리고 Session_OnStart 와
Session_OnEnd 이다
<script language=vbscript runat=server> '스크립트를 서버에서 실행
dim countfile_url, datefile_url
countfile_url = server.MapPath(".") & "\count.txt" ' 카운터 기록에 사용할 파일의 물리적 위치를 변수에 저장
datefile_url = server.MapPath(".") & "\date.txt" ' 날짜 기록에 사용할 파일의 물리적 위치를 변수에 저장
sub application_onstart '애플리케이션이 시작되면..
set fs=server.createobject("scripting.filesystemobject") '파일을 다루기 위한 개체 생성
set testfile=fs.opentextfile(countfile_url , 1) 'count.txt 를 읽기 모드로 읽어옴
application("nowcount")=0 '현재의 카운터를 0 으로 애플리케이션 변수에 할당 해줌
application("todaycount")=0 '오늘의 카운터를 0 으로 애플리케이션 변수에 할당
application("totalcount")=testfile.readline '누적카운터를 count.txt 파일에서 읽어온 내용으로 애플리케이션 변수에 할당
set fs=nothing '개체 소멸(서버의 리소스점유율을 감소)
set testfile=nothing '개체 소멸(서버의 리수스 점유율 감소)
end sub
sub application_onend '애플리케이션이 끝나면(실제로 제대로 동작하지 않음)
application.lock
set fs=server.createobject("scripting.filesystemobject")
set mfile=fs.createtextfile(countfile_url , true)
set fs=nothing
set mfile=nothing
set fs=server.createobject("scripting.filesystemobject")
set testfile=fs.opentextfile(countfile_url , 8)
testfile.writeline(application("totalcount"))
set fs=nothing
set testfile=nothing
application.unlock
end sub
sub session_onstart '세션이 시작되면(방문자의 방문이 있을시..)
session.timeout=15 ' 세션 종료시간을 15분으로 정함
session("connect_time")=now '접속한 시간을 기록
application.lock ' 에플리케이션 변수를 수정 못하게 일시적으로 잠금
application("nowcount") = application("nowcount") +1 '현재 카운터를 +1
application("todaycount") = application("todaycount")+1 '오늘 카운터를 +1
application("totalcount") = application("totalcount")+1 '누적 카운터를 +1
' ============================ 하루가 지나면 오늘의 카운터를 초기화 하기 위한 부분 =================
set fs=server.createobject("scripting.filesystemobject") '파일을 다루기 위한 개체 생성
set testfile=fs.opentextfile(datefile_url , 1) 'date.txt 파일을 읽기 모드로 오픈(날짜를 읽어옴)
dim today, nowdate
today = testfile.readline ' 읽어온 내용(날짜)을 today 변수에 저장
nowdate = day(now) ' 오늘 날짜를 nowdate 변수에 저장
if cint(today) <> cint(nowdate) then '읽어온 날짜와 접속시의 날짜를 비교해서 일치하지 않으면..
application("todaycount") = 1 ' 오늘 카운터를 1로 초기화
set testfile=nothing ' 개체소멸( 서버의 리소스 점유율 감소)
set makefile=fs.createtextfile(datefile_url , true) 'date.txt 파일을 새로 생성(기존 파일을 덮어씀)
set makefile=nothing '개체 소멸
set writefile=fs.opentextfile(datefile_url , 8) 'date.txt 파일을 쓰기모드로 오픈
writefile.writeline nowdate '접속시의 날짜를 파일에 씀
end if
' ============================ 하루가 지나면 오늘의 카운터를 초기화 하기 위한 부분 끝 =================
if application("totalcount") mod 2=0 then ' 누적 카운터가 짝수 번이 되면..
set fs=server.createobject("scripting.filesystemobject")
set mfile=fs.createtextfile(countfile_url , true) ' count.txt 파일을 새로 생성
set fs=nothing
set mfile=nothing
set fs=server.createobject("scripting.filesystemobject") '파일다루기 위한 개체 생성
set testfile=fs.opentextfile(countfile_url , 8) ' 생성한 파일을 쓰기모드로 오픈
testfile.writeline(application("totalcount")) ' 현재의 누적 카운터를 파일에 기록
set fs=nothing
set testfile=nothing
end if
application.unlock ' 변수 수정할 수있게 잠금을 품
end sub
sub session_onend '세션이 끝나면..
application("nowcount")=application("nowcount")-1 '현재 접속자수를 -1 함
end sub
</script>
| 
